cdo를 이용한 메시지 발송 방화벽 대처

cdo를 이용한 메시지 발송 방화벽 대처 [출처] cdo를 이용한 메시지 발송 방화벽 대처|작성자 항해자  

http://blog.naver.com/mission2hs/150029010629

Windows 2003 서버에서 CDO.Message를 이용한 메일 발송이 갑자기 오류가 났다.
오류명은 아래와 같다. 처음보는 오류.. ^^;

CDO.Message.1 오류 '80040220' 
"SendUsing"  구성파일 오류

원인을 찾아보니, 웹나이트 방화벽을 돌리기 시작한 시점부터 문제가 되었다.
그래서 웹나이트 방화벽을 잠시 끄고 발송해보니, 잘 되었다.

CDO 버전이 업그레이드 되면서, SendUsing을 정확히 지정해 주지 않으면 위와 같은
오류를 발생시킨다고 한다.
그래서 프로그램 쪽에서 메일 발송 함수를 아래와 같이 변경해 주니 잘 되었다.


Function fnEmail(eSendName,eSendMail,eGetName,eGetMail,eSubject,eBody)
    Dim SendMail, MailConfig
    Dim tmp, strTmp(4)

    Set SendMail   = Server.CreateObject("CDO.Message")
    Set MailConfig = SendMail.Configuration

    tmp = "http://schemas.microsoft.com/cdo/configuration"

    strTmp(0) = tmp &"/sendusing"

    strTmp(1) = tmp &"/smtpserverpickupdirectory"

    strTmp(2) = tmp &"/smtpserver"

    strTmp(3) = tmp &"/smtpserverport"

    strTmp(4) = tmp &"/smtpconnectiontimeout"

    With MailConfig.Fields
    ' 1 (로컬 SMTP) / 2 (외부 SMTP)
    .Item(strTmp(0)) = 1
    ' Pickup 디렉토리 설정
    .Item(strTmp(1)) = "C:\Inetpub\mailroot\Pickup"
    ' 호스트 설정
    .Item(strTmp(2)) = "127.0.0.1"
    ' SMTP Port
    .Item(strTmp(3)) = 25
    ' 연결 시간
    .Item(strTmp(4)) = 30
    .UpDate

 

    Set MailConfig = Nothing
    end With

 

    With SendMail
    .From     = eSendName &"<"& eSendMail &">"
    .To       = eGetName &"<"& eGetMail &">"
    .Subject  = eSubject
    .htmlBody = eBody
    .Send

    Set SendMail = Nothing

    end With

End Function


참고 자료 - http://cafe.naver.com/basicwebper.cafe?iframe_url=/ArticleRead.nhn%3Farticleid=4 

[출처] cdo를 이용한 메시지 발송 방화벽 대처|작성자 항해자