xmlHTTP를 이용해서 웹페이지 가져오기

<%

' ===========================
'  Function to GetHTMLBin
' ===========================
Function GetHTMLBin(URLaddress)
Dim Http
Set Http = CreateObject("Microsoft.XMLHTTP")
Http.Open "GET", URLaddress, False
Http.Send
GetHTMLBin = Http.responseBody
Set Http = Nothing
End Function

' ===========================
'  Function to BinToText
' ===========================
Function BinToText(varBinData, intDataSizeInBytes)    ' as String
Const adFldLong = &H00000080
Const adVarChar = 200
Set objRS = CreateObject("ADODB.Recordset")
objRS.Fields.Append "txt", adVarChar, intDataSizeInBytes, adFldLong
objRS.Open
objRS.AddNew
objRS.Fields("txt").AppendChunk varBinData
BinToText = objRS("txt").Value
objRS.Close
Set objRS = Nothing
End Function

GetURL = "http://www.naver.com/"

HTMLBin = GetHTMLBin(GetURL)
html = BinToText(HTMLBin,32000) 

%>
<%=html%>

xmlHTTP를 사용해서 웹페이지를 긁어왔을때 한글인경우 깨지죠?
그럴때 위에 함수 사용하세요
텍스트로 받지 않고 body로 받아서 다시 변환시켜주는 함수입니다.

웹페이지 긁는거 어떤분이 질답란에 올리셨는데 답변을 다는분이 아무도 없는거 같아서 여기에 올립니다.